;+
; NAME:
;  yl89l77
; PURPOSE: (one line)
;  radiative cooling rate (Q) from Yelle and Lunine 1989 FOR 7.7 um
; CALLING SEQUENCE:
;  yl89l77, t,n,mixrat, h, p10=p10, distau=distau
; INPUTS:
;  t - temperature (K)
;  n - number density of atmosphere (cm^-3)
;  mixrat - CH4 mixing ratio, n_CH4 / n (unitless)
; KEYWORD INPUT PARAMETERS
;  p10 - probability that a V-T transition occurs during a collision
; OUTPUTS:
;  l77 - cooling rate (erg/cm^3/s)
;  dl77 - temperature derivative d l77/dT (erg/cm^3/s/K) at constant pressure
; MODIFICATION HISTORY:
;  Written 2004 Apr, by Leslie Young, SwRI
;  Modified 2006 Dec 26 LAY (added dl77)
;-
pro yl89l77, t, n, mixrat, l77, dl77, p10=p10, distau=distau

if not keyword_set(p10) then p10 = 1e-6
if not keyword_set(distau) then distau=30.121473

    physconstants
    
; set up constants
	
    wl_l = 7.8                  ; micron
    wn_l = 1e4/wl_l             ; wavenumber in invcm
    nu = !phys.c * wn_l
    g = 3                       ; degeneracy
    a10_l = 2.56                ; s^-1
    
	moldiam = 3.7405e-8
	mun2 = 28.
	much4 = 16.0426
	molwgt = (mun2*much4)/(mun2+much4)

    hnu = (!phys.h*nu)
    hnuk = hnu/(!phys.k)
    
   	vteff = yl89_vtefficiency(t, n, a10_l, p10, moldiam, molwgt)
	eps = vteff/(1.d + vteff)

    
    l77 = g * eps * n * mixrat * hnu * a10_l * exp(- hnuk/t)

    dl77 = l77 * (1 + 0.5/(1+vteff) + hnuk/t) / t
    
end