;+
; NAME:
;  print_traceback
; PURPOSE: (one line)
;  print traceback info
; DESCRIPTION:
;  
; CATEGORY:
;  Util
; CALLING SEQUENCE:
;  print_traceback, string, /time, /routine=routine, /filemame,
;     /basename, /line, /cr, trace=trace
; INPUTS:
;   str optional string
; OPTIONAL INPUT PARAMETERS:
; KEYWORD INPUT PARAMETERS:
;  datetime = 1 for a time stamp at the start
;  routine = 1 to print the routine name
;  filename = 1 to print the filename
;  basename = 1 to print the base filename
;  line = 1 to print the the linenumber
;  CR = 1 for a carriage return at the end
; KEYWORD OUTPUT PARAMETERS:
;  none
; OUTPUTS:
;  trace = the trace structure of whatever called print_traceback
; COMMON BLOCKS:
;  None
; SIDE EFFECTS:
;  prints [<time> <routine> <file> <basefile> <line>] str <cr>
; RESTRICTIONS:
;  None
; PROCEDURE:
; MODIFICATION HISTORY:
;  2010 08 20 Leslie Young, SwRI
;-

pro print_traceback, str, datetime=datetime, routine=routine, filename=filename, $
                     basename=basename, line=line, cr=cr, trace=trace
    tracestr = ''
    if keyword_set(datetime) then tracestr = tracestr + systime()+' '
    trace_arr = scope_traceback(/str)
    trace = trace_arr[n_elements(trace_arr)-2]
    if keyword_set(routine) then tracestr = tracestr + trace.routine+' '
    if keyword_set(filename) then tracestr = tracestr + trace.filename+' '
    if keyword_set(basename) then tracestr = tracestr + file_basename(trace.filename)+' '
    if keyword_set(line) then tracestr = tracestr + strtrim(string(trace.line),2)+' '
    tracestr = strtrim(tracestr,2)
    if strlen(tracestr) gt 0 then begin
       writeu, -1, '['
       writeu, -1, tracestr
       writeu, -1, ']'
       if keyword_set(str) then  writeu, -1, ' '
    endif
    if n_elements(str) gt 0 then writeu, -1, str
    if keyword_set(cr) then print, ''
end