;+
; NAME:
;  rt_vtefficiency
; PURPOSE: (one line)
;  Return the ratio of collision rate to spontaneous deacy rate
; DESCRIPTION:
;  Return the ratio of collision rate to deacy rate
; 
;  See Yelle 1991. "Non-LTE models of Titan's upper atmosphere,"
;  ApJ 383, 380-400, eqn 10.
; 
; CATEGORY:
;  RT
; CALLING SEQUENCE:
;  eps = rt_vtefficiency(t, n, a10, p10, moldiam, molwgt)
; INPUTS:
;  t - temperature (K)
;  n - number density of the background atmosphere (cm^-3)
;  a10 - Einstein A10 coefficient (s^-1)
;  p10 - collision probability (unitless)
;  moldiam - reduced diameter of the molecules (cm)
;  molwgt - reduced molecular weight
; OPTIONAL INPUT PARAMETERS:
;  none
; KEYWORD INPUT PARAMETERS:
;  none
; KEYWORD OUTPUT PARAMETERS:
;  none
; OUTPUTS:
;  collision rate/deexcitation rate
; COMMON BLOCKS:
;  None
; SIDE EFFECTS:
; RESTRICTIONS:
;  None
; PROCEDURE:
; MODIFICATION HISTORY:
;  Written 2004 Mar 17, Leslie Young SwRI
;  based on epslnf, written by Roger Yelle, 1990
;-


function rt_vtefficiency, t, n, a10, p10, moldiam, molwgt

physconstants

z10 = (moldiam^2.)*sqrt( 8.d * !dpi * !phys.k * t/ (molwgt * !phys.m_u) )
c10 = p10*z10*n
epsln = c10/a10

return, epsln

end


pro rt_vtefficiencyTEST
; test case for CH4 in N2 at 100 K, 1 microbar 

physconstants

t =100.
p = 1.
n = p/(!phys.k * t)
a10 = 24.80
p10 = 1e-6
;p10 = 2.000e-2
moldiam = 3.7405e-8
mun2 = 28.
much4 = 16.0426
molwgt = (mun2*much4)/(mun2+much4)

eps = rt_vtefficiency(t, n, a10, p10, moldiam, molwgt)
print, '; rt_vtefficiencyTEST: for CH4 in N2 at 100 K, 1 microbar, eps = ', eps

end