;+
; NAME:
;   et2utc
;
; PURPOSE:
;   converts ET to strings (ET = TDB seconds after J2000)
;
; DESCRIPTION:
;   converts ET to strings (ET = TDB seconds after J2000)
;
; CALLING SEQUENCE:
;   utc = et2utc(et) 
;
; INPUTS:
;   et - may be a double, or an array or matrix of doubles
;
; KEYWORDS
;   format =the scalar string format of the output time string,
;               it may be any of the following:
;      "C"      Calendar format, UTC
;      "D"      Day-of-Year format, UTC
;      "J"      Julian Date format, UTC
;      "ISOC"   ISO Calendar format, UTC
;      "ISOD"   ISO Day-of-Year format, UTC
;      DEFAULT IS "C"
;
;   prec     the scalar integer number of decimal places of precision to 
;            which fractional seconds (for Calendar and Day-of-Year
;            formats) or days (for Julian Date format) are to be 
;            computed 
;      DEFAULT IS 3 (or 5 for format = 'J')
; OUTPUTS:
;  utc - String representation of et. Same dimensions as et.
; 
; PROCEDURE:
;  Just calls cspice_et2utc 
;  REVISON HISTORY:
;   2006 Jan 05 Leslie Young.  Based on single_eph
;-

function et2utc, et, format=format, prec=prec

    naifinit

    if not keyword_set(format) then format = 'C'
    if not keyword_set(prec) then begin
        if format eq 'J' then prec = 5 else prec = 3
    end

    if isarray(et) then begin
        dim = size(et, /dim)
        utc = make_array(dim,/string)
        n = n_elements(et)
        for i=0, n-1 do begin
            CSPICE_ET2UTC, et[i], format, prec, utci
            utc[i] = utci
        end
        return, utc
    endif else begin
        CSPICE_ET2UTC, et, format, prec, utc
        return, utc
    end
    
end