;+
; NAME:
;  n2latentheat
; PURPOSE: (one line)
;  Return latent heat of sublimation of N2 in erg/g from Brown & Ziegler 1980
; CATEGORY:
;  Volatile Transport
; CALLING SEQUENCE:
;  latentheat = n2latentheat(t)
; INPUTS:
;  t : temperature, K
; KEYWORD INPUTS
;  None
; OUTPUTS:
;  latentheat : latent heat of sublimation in erg/g
; OPTIONAL OUTPUT
;  None
; RESTRICTIONS:
; PROCEDURE:
;  This function implements the tables of Brown and Zeigler 
; MODIFICATION HISTORY:
;  Written 2011 Jan 25, by Leslie Young, SwRI
;-
function n2latentheat, t
physconstants
if isarray(t) then begin
   l = 0. * t
   for i = 0, n_elements(l)-1 do l[i] = n2latentheat(t[i])
   return, l
endif

; Return N2 latent heat of sublimation, in erg/g, as a function of temperature
a_liq  =[1.51050147e1, -6.15496072e2, -2.31314834e3, -5.89850934e4, 0.]
a_beta= [1.64302619e1, -6.50497257e2, -8.52432256e3,  1.55914234e5, -1.06368300e6]
a_alpha=[1.88550118e1, -8.57102332e2, -1.01891053e3,  1.28466570e4, -4.82177497e4]
a=a_beta
if t eq 0. then return, 0.
if t lt 35.62 then a=a_alpha
if t gt 63.152 then a=a_liq
l = -total( (findgen(4)+1) * t^(- (findgen(4)) ) * a[1:4]) * !phys.k / (28.0061 * !phys.m_u)

return, l
end